1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
|
; Copyright 2015 Egor Tensin <Egor.Tensin@gmail.com>
; This file is licensed under the terms of the MIT License.
; See LICENSE.txt for details.
.586
.xmm
.model flat
.data
align 10h
key_schedule oword 15 dup(0)
align 10h
inverse_key_schedule oword 15 dup(0)
.code
@aes256cbc_encrypt@52 proc
call expand_keys_256cbc
pxor xmm0, [ecx]
pxor xmm0, [key_schedule]
aesenc xmm0, [key_schedule + 10h]
aesenc xmm0, [key_schedule + 20h]
aesenc xmm0, [key_schedule + 30h]
aesenc xmm0, [key_schedule + 40h]
aesenc xmm0, [key_schedule + 50h]
aesenc xmm0, [key_schedule + 60h]
aesenc xmm0, [key_schedule + 70h]
aesenc xmm0, [key_schedule + 80h]
aesenc xmm0, [key_schedule + 90h]
aesenc xmm0, [key_schedule + 0A0h]
aesenc xmm0, [key_schedule + 0B0h]
aesenc xmm0, [key_schedule + 0C0h]
aesenc xmm0, [key_schedule + 0D0h]
aesenclast xmm0, [key_schedule + 0E0h]
ret
@aes256cbc_encrypt@52 endp
expand_keys_256cbc proc
lea edx, [key_schedule + 20h]
movdqa [key_schedule], xmm1
movdqa [key_schedule + 10h], xmm2
aeskeygenassist xmm7, xmm2, 1h
pshufd xmm7, xmm7, 0FFh
call gen_round_key
aeskeygenassist xmm7, xmm2, 0
pshufd xmm7, xmm7, 0AAh
call gen_round_key
aeskeygenassist xmm7, xmm2, 2h
pshufd xmm7, xmm7, 0FFh
call gen_round_key
aeskeygenassist xmm7, xmm2, 0
pshufd xmm7, xmm7, 0AAh
call gen_round_key
aeskeygenassist xmm7, xmm2, 4h
pshufd xmm7, xmm7, 0FFh
call gen_round_key
aeskeygenassist xmm7, xmm2, 0
pshufd xmm7, xmm7, 0AAh
call gen_round_key
aeskeygenassist xmm7, xmm2, 8h
pshufd xmm7, xmm7, 0FFh
call gen_round_key
aeskeygenassist xmm7, xmm2, 0
pshufd xmm7, xmm7, 0AAh
call gen_round_key
aeskeygenassist xmm7, xmm2, 10h
pshufd xmm7, xmm7, 0FFh
call gen_round_key
aeskeygenassist xmm7, xmm2, 0
pshufd xmm7, xmm7, 0AAh
call gen_round_key
aeskeygenassist xmm7, xmm2, 20h
pshufd xmm7, xmm7, 0FFh
call gen_round_key
aeskeygenassist xmm7, xmm2, 0
pshufd xmm7, xmm7, 0AAh
call gen_round_key
aeskeygenassist xmm7, xmm2, 40h
pshufd xmm7, xmm7, 0FFh
call gen_round_key
call invert_key_schedule
ret
gen_round_key:
movdqa xmm6, xmm1
pslldq xmm6, 4
pxor xmm1, xmm6
pslldq xmm6, 4
pxor xmm1, xmm6
pslldq xmm6, 4
pxor xmm1, xmm6
pxor xmm1, xmm7
movdqa [edx], xmm1
add edx, 10h
movdqa xmm7, xmm1
movdqa xmm1, xmm2
movdqa xmm2, xmm7
ret
invert_key_schedule:
movdqa xmm7, [key_schedule]
movdqa xmm6, [key_schedule + 0E0h]
movdqa [inverse_key_schedule], xmm6
movdqa [inverse_key_schedule + 0E0h], xmm7
aesimc xmm7, [key_schedule + 10h]
aesimc xmm6, [key_schedule + 0D0h]
movdqa [inverse_key_schedule + 10h], xmm6
movdqa [inverse_key_schedule + 0D0h], xmm7
aesimc xmm7, [key_schedule + 20h]
aesimc xmm6, [key_schedule + 0C0h]
movdqa [inverse_key_schedule + 20h], xmm6
movdqa [inverse_key_schedule + 0C0h], xmm7
aesimc xmm7, [key_schedule + 30h]
aesimc xmm6, [key_schedule + 0B0h]
movdqa [inverse_key_schedule + 30h], xmm6
movdqa [inverse_key_schedule + 0B0h], xmm7
aesimc xmm7, [key_schedule + 40h]
aesimc xmm6, [key_schedule + 0A0h]
movdqa [inverse_key_schedule + 40h], xmm6
movdqa [inverse_key_schedule + 0A0h], xmm7
aesimc xmm7, [key_schedule + 50h]
aesimc xmm6, [key_schedule + 90h]
movdqa [inverse_key_schedule + 50h], xmm6
movdqa [inverse_key_schedule + 90h], xmm7
aesimc xmm7, [key_schedule + 60h]
aesimc xmm6, [key_schedule + 80h]
movdqa [inverse_key_schedule + 60h], xmm6
movdqa [inverse_key_schedule + 80h], xmm7
aesimc xmm7, [key_schedule + 70h]
movdqa [inverse_key_schedule + 70h], xmm7
ret
expand_keys_256cbc endp
@aes256cbc_decrypt@52 proc
call expand_keys_256cbc
pxor xmm0, [inverse_key_schedule]
aesdec xmm0, [inverse_key_schedule + 10h]
aesdec xmm0, [inverse_key_schedule + 20h]
aesdec xmm0, [inverse_key_schedule + 30h]
aesdec xmm0, [inverse_key_schedule + 40h]
aesdec xmm0, [inverse_key_schedule + 50h]
aesdec xmm0, [inverse_key_schedule + 60h]
aesdec xmm0, [inverse_key_schedule + 70h]
aesdec xmm0, [inverse_key_schedule + 80h]
aesdec xmm0, [inverse_key_schedule + 90h]
aesdec xmm0, [inverse_key_schedule + 0A0h]
aesdec xmm0, [inverse_key_schedule + 0B0h]
aesdec xmm0, [inverse_key_schedule + 0C0h]
aesdec xmm0, [inverse_key_schedule + 0D0h]
aesdeclast xmm0, [inverse_key_schedule + 0E0h]
pxor xmm0, [ecx]
ret
@aes256cbc_decrypt@52 endp
end
|
