blob: 6782770ac10c92b6e96ac9d55010da9e850a6373 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
@rem Copyright (c) 2015 Egor Tensin <Egor.Tensin@gmail.com>
@rem This file is part of the "Windows 7 drivers" project.
@rem For details, see https://github.com/egor-tensin/windows7-drivers.
@rem Distributed under the MIT License.
@setlocal enabledelayedexpansion
@echo off
call check_env.bat || exit /b !errorlevel!
if [%BUILD_ALT_DIR%] == [] goto :ddk_not_set
if [%_BUILDARCH%] == [] goto :ddk_not_set
if not exist %root%\sign.bat (
echo Error: %root%\sign.bat is missing ^(don^'t know how to sign drivers^)
exit /b 1
)
where build.exe >nul 2>&1 || goto :build_not_found
where signtool.exe >nul 2>&1 || goto :signtool_not_found
where makecert.exe >nul 2>&1 || goto :makecert_not_found
exit /b 0
:ddk_not_set
echo Error: either %%BUILD_ALT_DIR%% or %%_BUILDARCH%% are not set ^(perhaps you forgot to set up the WinDDK environment^)
exit /b 1
:build_not_found
echo Error: build.exe not found ^(perhaps you forgot to set up the WinDDK environment^)
exit /b 1
:signtool_not_found
echo Error: signtool.exe not found ^(perhaps you forgot to set up the WinDDK environment^)
exit /b 1
:makecert_not_found
echo Error: makecert.exe not found ^(perhaps you forgot to set up the WinDDK environment^)
exit /b 1
|
